DOCUMENT:Q184740  28-APR-1998  [vbwin]
TITLE   :HOWTO: Call Functions Using the Script Control
PRODUCT :Microsoft Visual Basic for Windows
PROD/VER:WINDOWS:4.0,5.0
OPER/SYS:WINDOWS
KEYWORDS:kbVBp kbVBp400 kbVBp500 kbVBp600 kbScript kbCtrl

======================================================================
---------------------------------------------------------------------
The information in this article applies to:

 - Microsoft Visual Basic Standard, Professional, and Enterprise Editions,
   32-bit only, for Windows, version 4.0
 - Microsoft Visual Basic Learning, Professional, and Enterprise Editions
   for Windows, version 5.0
 - Microsoft Visual Basic for Applications version 5.0
---------------------------------------------------------------------

SUMMARY
=======

This article provides sample code for the Script control that demonstrates
various methods of calling script functions from Visual Basic.

MORE INFORMATION
================

IMPORTANT: Microsoft provides programming examples for illustration only,
without warranty either expressed or implied, including, but not limited
to, the implied warranties of merchantability and/or fitness for a
particular purpose. This article assumes that you are familiar with the
programming language being demonstrated and the tools used to create and
debug procedures.

The Script control can host VBScript, JavaScript, and any other compliant
scripting language, so your users can script your application in a similar
manner to using VBScript or JavaScript to provide additional functionality
for Web pages.

The following article in the Microsoft Knowledge Base describes how to
obtain the Script control:

   ARTICLE-ID: Q184739
   TITLE     : FILE: Script Control

The Script control provides three methods for calling Sub and Function
script routines:

 - Eval: Evaluates a text expression.
 - Run: Runs a named Sub or Function.
 - Execute: Executes a script statement.

Eval
----

The calling convention is:

  Result = ScriptControl.Eval("some text expression")

You can use this method to call both intrinsic script functions, as well as
user functions. Function arguments are passed as literal values in the
expression text and can be either hard-coded or concatenated from a
variable.

NOTE: This method cannot be used to call Subroutines.

Run
---

The calling convention is:

  Result = ScriptControl.Run("Name", arg1, arg2, ... argn)

You can use this method to call Subroutines, in which case the Result
returned is empty and you can use the alternate calling convention to
ignore the return result:

  ScriptControl.Run "Name", arg1, arg2, ... argn

NOTE: Name is the name of the Sub or Function, and arg1 ... argn are
optional depending on the Sub or Function in question.

Execute
-------

The calling convention is:

  ScriptControl.Execute "statement text"

This method allows you to call any intrinsic statement or Sub routine. You
can also use it to call functions, but the return result is dropped.

Example
-------

1. In Visual Basic, create a new project (Form1 is created by default).

2. Click Components on the Project menu, and then select the "Microsoft
   Script Control 1.0" check box.

3. Add the Script control (ScriptControl1), a text box (Text1), and a
   command button (Command1) to a form. Set the MultiLine property of the
   text box to TRUE.

4. Add the following code to Form1:

      Private Sub Command1_Click()
        With ScriptControl1
          ' Set script language (VBScript is the default).
          .Language = "VBScript"
          ' Set UI interaction (TRUE is the default).
          .AllowUI = True
          ' Copy the script to the control.
          .AddCode Text1.Text
          ' Demonstrate the Eval method.
          Debug.Print .Eval("AddTwo(5,7)")
          ' Demonstrate the Run method both with and without return values.
          .Run "Hello", "Jane Doe"
          Debug.Print .Run("Hello", "James Smith")
          .Run "AddTwo", 4, 6
          Debug.Print .Run("AddTwo", 7, 8)
          ' Demonstrate the ExecuteStatement method.
          .ExecuteStatement "Hello ""Sue Smith"""
          .ExecuteStatement "AddTwo 9,18"
          .ExecuteStatement "MsgBox CStr(AddTwo(3,8))"
        End With
      End Sub

5. Run Form1, and open the Debug window.

6. Type the following script in the text box:

      Sub Hello(YourName)
        MsgBox "Hello " & YourName
      End Sub

      Function AddTwo(X1, X2)
        AddTwo = X1 + X2
      End Function

7. Click the command button.

   NOTE: The following two statements do not produce an output because the
   function return is lost and the code does not output the result through
   any other means, such as a global variable or message box.

      .Run "AddTwo", 4, 6
      .ExecuteStatement "AddTwo 9,18"

REFERENCES
==========

For information about obtaining the Script control, please see the
following article in the Microsoft Knowledge Base:

   ARTICLE-ID: Q184739
   TITLE     : FILE: Script Control


(c) Microsoft Corporation 1998, All Rights Reserved. Contributions by
Malcolm Stewart, Microsoft Corporation

Additional query words:
======================================================================
Keywords          : kbVBp kbVBp400 kbVBp500 kbVBp600 kbScript kbCtrl
Version           : WINDOWS:4.0,5.0
Platform          : WINDOWS
Issue type        : kbhowto

=============================================================================

THE INFORMATION PROVIDED IN THE MICROSOFT KNOWLEDGE BASE IS
PROVIDED "AS IS" WITHOUT WARRANTY OF ANY KIND.  MICROSOFT DISCLAIMS
ALL WARRANTIES, EITHER EXPRESS OR IMPLIED, INCLUDING THE WARRANTIES
OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE.  IN NO
EVENT SHALL MICROSOFT CORPORATION OR ITS SUPPLIERS BE LIABLE FOR
ANY DAMAGES WHATSOEVER INCLUDING DIRECT, INDIRECT, INCIDENTAL,
CONSEQUENTIAL, LOSS OF BUSINESS PROFITS OR SPECIAL DAMAGES, EVEN IF
MICROSOFT CORPORATION OR ITS SUPPLIERS HAVE BEEN ADVISED OF THE
POSSIBILITY OF SUCH DAMAGES.  SOME STATES DO NOT ALLOW THE EXCLUSION
OR LIMITATION OF LIABILITY FOR CONSEQUENTIAL OR INCIDENTAL DAMAGES
SO THE FOREGOING LIMITATION MAY NOT APPLY.

Copyright Microsoft Corporation 1998.